Enhanced Guide
Values of this syntax suggest criteria to be used in constructing filters to search for entries of a particular object class. The criteria are combinations of attribute types and filter operators.
For example, the value person#(sn$EQ)#oneLevel
suggests searching for person entries
with an equality filter to match surname (SN) attribute values
with a scope of one level below the base DN.
The syntax follows this ABNF:
EnhancedGuide = object-class SHARP WSP criteria WSP
SHARP WSP subset
object-class = WSP oid WSP
subset = "baseobject" / "oneLevel" / "wholeSubtree"
criteria = and-term *( BAR and-term )
and-term = term *( AMPERSAND term )
term = EXCLAIM term /
attributetype DOLLAR match-type /
LPAREN criteria RPAREN /
true /
false
match-type = "EQ" / "SUBSTR" / "GE" / "LE" / "APPROX"
true = "?true"
false = "?false"
BAR = %x7C ; vertical bar ("|")
AMPERSAND = %x26 ; ampersand ("&")
EXCLAIM = %x21 ; exclamation mark ("!")
WSP = 0*SPACE ; zero or more " "
DOLLAR = %x24 ; dollar sign ("$")
SPACE = %x20 ; space (" ")
SHARP = %x23 ; octothorpe (or sharp sign) ("#")
LPAREN = %x28 ; left paren ("(")
RPAREN = %x29 ; right paren (")")
attributetype = oid
oid = descr / numericoid
descr = keystring
numericoid = number 1*( DOT number )
keystring = leadkeychar *keychar
leadkeychar = ALPHA
keychar = ALPHA / DIGIT / HYPHEN
number = DIGIT / ( LDIGIT 1*DIGIT )
ALPHA = %x41-5A / %x61-7A ; "A"-"Z" / "a"-"z"
DIGIT = %x30 / LDIGIT ; "0"-"9"
LDIGIT = %x31-39 ; "1"-"9"
HEX = DIGIT / %x41-46 / %x61-66 ; "0"-"9" / "A"-"F" / "a"-"f"
The syntax corresponds to
the EnhancedGuide ASN.1 type defined by X.520.
Origin |
|
Description |
Enhanced Guide |
OID |
1.3.6.1.4.1.1466.115.121.1.21 |