Substring Assertion

Values of this syntax hold sequences of zero or more character substrings used as an argument for substring extensible matching of character string attribute values.

Such are the match values of matching rule assertions. They are not used in attribute values or in a substring filter.

Each substring is a string of one or more characters from the Universal Character Set (UCS). Zero-length substrings are not permitted.

Values follow this ABNF:

SubstringAssertion = [ initial ] any [ final ]

initial  = substring
any      = ASTERISK *(substring ASTERISK)
final    = substring
ASTERISK = %x2A  ; asterisk ("*")

substring           = 1*substring-character
substring-character = %x00-29
                      / (%x5C "2A")  ; escaped "*"
                      / %x2B-5B
                      / (%x5C "5C")  ; escaped "\"
                      / %x5D-7F
                      / UTFMB

UTFMB   = UTF2 / UTF3 / UTF4
UTF1    = %x00-7F
UTF2    = %xC2-DF UTF0
UTF3    = %xE0 %xA0-BF UTF0 / %xE1-EC 2(UTF0) /
          %xED %x80-9F UTF0 / %xEE-EF 2(UTF0)
UTF4    = %xF0 %x90-BF 2(UTF0) / %xF1-F3 3(UTF0) /
          %xF4 %x80-8F 2(UTF0)

The syntax corresponds to the SubstringAssertion ASN.1 type defined in X.520.

Origin RFC 4517
Description Substring Assertion
Read a different version of :