Teletex Terminal Identifier

Values of this syntax hold identifiers and, optionally, parameters of teletex terminals.

Values follow this ABNF:

teletex-id = ttx-term *(DOLLAR ttx-param)
ttx-term   = PrintableString          ; terminal identifier
ttx-param  = ttx-key COLON ttx-value  ; parameter
ttx-key    = "graphic" / "control" / "misc" / "page" / "private"
ttx-value  = *ttx-value-octet
ttx-value-octet = %x00-23
                  / (%x5C "24")  ; escaped "$"
                  / %x25-5B
                  / (%x5C "5C")  ; escaped "\"
                  / %x5D-FF

DOLLAR             = %x24 ; dollar sign ("$")
PrintableString    = 1*PrintableCharacter
PrintableCharacter = ALPHA / DIGIT / SQUOTE / LPAREN / RPAREN /
                     PLUS / COMMA / HYPHEN / DOT / EQUALS /
                     SLASH / COLON / QUESTION / SPACE
ALPHA              = %x41-5A / %x61-7A   ; "A"-"Z" / "a"-"z"
DIGIT              = %x30 / LDIGIT       ; "0"-"9"
LDIGIT             = %x31-39             ; "1"-"9"
SPACE              = %x20 ; space (" ")
SQUOTE             = %x27 ; single quote ("'")
LPAREN             = %x28 ; left paren ("(")
RPAREN             = %x29 ; right paren (")")
PLUS               = %x2B ; plus sign ("+")
COMMA              = %x2C ; comma (",")
HYPHEN             = %x2D ; hyphen ("-")
DOT                = %x2E ; period (".")
EQUALS             = %x3D ; equals sign ("=")
SLASH              = %x2F ; forward slash ("/")
COLON              = %x3A ; colon (":")
QUESTION           = %x3F ; question mark ("?")
    

The syntax corresponds to the TeletexTerminalIdentifier ASN.1 type defined in X.520.

Origin RFC 4517
Description Teletex Terminal Identifier
OID 1.3.6.1.4.1.1466.115.121.1.51
Read a different version of :